[tintin++]破阵辅助~~
本帖最后由 django 于 2017-2-28 12:43 AM 编辑由于tintin++无法显示闪烁字，导致无法做破阵，所以才有了这个
断断续续写了两三天，非自动，手动辅助计算出口的，需要的拿去
ask.job 在陆乘风处要job
ask.over 要奖励
ask.fail 失败
zhanbu.maze 到地点后开始占卜破阵
zhanbu.place 显示破阵地点
#split;
#config repeat on;
#alias ask.job {
#class ask.job open;
#action {你对陆乘风道：“听闻近来有人冒名桃花岛弟子在%S布下迷阵行恶，我愿代劳除去此獠。”} {
#var jobplace %%1;
zhanbu.place;
#class ask.job kill;
};
#class ask.job close;
ask lu about 破阵;
};
#alias ask.over {ask lu about 破阵奖励};
#alias ask.fail {ask lu about 破阵失败};
#alias zhanbu.place {
#echo <cfa><EAA>=================================================;
#echo <cfa><EAA> 破阵地点：<AAA> $jobplace。;
#echo <cfa><EAA>=================================================;
};
#alias zhanbu.maze {
#class zhanbu.maze open;
#var pos {{nw}{2}{n}{2}{ne}{2}{w}{2}{e}{2}{sw}{2}{s}{2}{se}{2}};
#var posstep 0;
#var direc {nw;n;ne;w;e;sw;s;se};
#foreach $direc direction {
#var exec {#alias $direction {#var pace $direction;#send $direction}};
$exec;
};
#function printdirec {
#var printtext { 经推算，正确方向可能为：};
#foreach $direc direction {
#if {$pos.$direction} {
#var printtext $printtext $direction;
};
};
#echo <cfa><EAA>=================================================;
#echo <cfa>$printtext;
#echo <cfa><EAA>=================================================;
#return #cr;
};
#action {~{\e\[5m\e\[42|\e\[42}%S{\e\[5m\e\[42|\e\[42}%S{\e\[5m\e\[42|\e\[42}} {
#if {$posstep} {
#var posstep 0;
#if {"%%1" == "\e[42"} {#var pos.sw 0};
#elseif {"%%1" == "\e[5m\e[42" && !$pos.sw} {#var pos.sw 0};
#else {#var pos.sw 1};
#if {"%%3" == "\e[42"} {#var pos.s 0};
#elseif {"%%3" == "\e[5m\e[42" && !$pos.s} {#var pos.s 0};
#else {#var pos.s 1};
#if {"%%5" == "\e[42"} {#var pos.se 0};
#elseif {"%%5" == "\e[5m\e[42" && !$pos.se} {#var pos.se 0};
#else {#var pos.se 1};
@printdirec{};
};
#else {
#var posstep 1;
#if {"%%1" == "\e[42"} {#var pos.nw 0};
#elseif {"%%1" == "\e[5m\e[42" && !$pos.nw} {#var pos.nw 0};
#else {#var pos.nw 1};
#if {"%%3" == "\e[42"} {#var pos.n 0};
#elseif {"%%3" == "\e[5m\e[42" && !$pos.n} {#var pos.n 0};
#else {#var pos.n 1};
#if {"%%5" == "\e[42"} {#var pos.ne 0};
#elseif {"%%5" == "\e[5m\e[42" && !$pos.ne} {#var pos.ne 0};
#else {#var pos.ne 1};
};
} {1};
#action {~{\e\[5m\e\[42|\e\[42}%S{\e\[5m\e\[42|\e\[42}} {
#if {"%%1" == "\e[42"} {#var pos.w 0};
#elseif {"%%1" == "\e[5m\e[42" && !$pos.w} {#var pos.w 0};
#else {#var pos.w 1};
#if {"%%3" == "\e[42"} {#var pos.e 0};
#elseif {"%%3" == "\e[5m\e[42" && !$pos.e} {#var pos.e 0};
#else {#var pos.e 1};
} {2};
#action {你尝试破阵，可惜选择了错误的方向，损失了一些气血和内力。} {
#var pos.$pace 0;
};
#action {这里的迷阵在你眼中如同儿戏一般。} {
#var pos {{nw}{2}{n}{2}{ne}{2}{w}{2}{e}{2}{sw}{2}{s}{2}{se}{2}};
#var posstep 0;
};
#action {破阵失败！这里的真相恐怕永远被掩盖。} {
#class zhanbu.maze kill;
#echo <cfa><EAA>=================================================;
#echo <cfa> 破阵失败！;
#echo <cfa><EAA>=================================================;
};
#action {你彻底破解了这里的迷阵！} {
#class zhanbu.maze kill;
#echo <cfa><EAA>=================================================;
#echo <cfa> 破阵成功！;
#echo <cfa><EAA>=================================================;
};
#action {看起来%S想杀死你！} {
#class zhanbu.maze.kill open;
#action {大 恶 %%1(%D)} {
#format npcid %l %%%1;
kill $npcid;
};
#action {%%1道：想不到我最终还是失败了！哎！} {
#class zhanbu.maze.kill kill;
#echo <cfa><EAA>=================================================;
#echo <cfa> 破阵任务成功完成！;
#echo <cfa><EAA>=================================================;
s;
};
#action {你在攻击中不断积蓄攻势。(气势：%d%)} {
#if {%%%1 >= 8} {do 3 perform fuxue-shou.fuxue};
};
#class zhanbu.maze.kill close;
};
#class zhanbu.maze close;
jiali max;
yun recover;
yun regenerate;
yun qi;
yun powerup;
zhanbu -maze;
};
Linux下 没有斜体,没有闪烁. 嘿嘿 Linux下 没有斜体,没有闪烁. 嘿嘿
wfoxp 发表于 2017-2-27 11:12 PM http://pkuxkx.com/forum/images/common/back.gif
正是因为如此，所以花了两三天功夫研究了一下，做出了这个，效率提升很多 本帖最后由 hoof 于 2017-8-7 05:44 AM 编辑
还能用吗？ 我试了试 没有正确方向出来
看了看debug, 33行 不知为什么总是#if 不为真， 尽管确实为1 搞定了， 把所有的pos.替换成pos[]就可以了， 按理说两种写法都可以的， 不知为何
谢谢分享 感谢大神，参考价值超高
页:
[1]