暂时发现俩个，就是红色字体的
//步骤一:先做好主体部分:接任务做任务完成任务下线
#tri {你向多隆打听有关『守门』的消息。} {#t+ job}
//多隆的回答全部取一个class名:job
#tri {这里没有这个人。} {#t- job;#wa 20000;ask duo about job} {job}
#tri {但是很显然的，多隆现在的状况没有办法给你任何答覆。} {#t- job;#wa 20000;ask duo about job} {job}
//多隆死了或者晕了，等待20秒再要任务
#tri {多隆说道：「大人位高权重，已经不用干这种活了。」} {#t- job;#play xxx.wav;#var zhanghao {};#var mima {};quit} {job}
//守门结束了，清空帐号密码阻止自动连线，播放一首音乐轻松下
#tri {多隆说道：「大人需要升迁之后再继续作守门任务。」}
{#t- job;do 3 s;do 4 w;s;s;ask ming zhu about bonus;ask ming zhu about 升迁;n;n;do 4 e;do 3 n;ask duo about 守门} {job}
#tri {多隆说道：「守门只有早晚两班，你到时间再来吧。」} {#t- job;#timer on} {job}
//上线时间不一定准确,此时打开tick timer以确保不会发呆10分钟掉线,然后等待天色触发
//设置tick timer,每300秒输入1个hp命令,仅仅为了保证不会发呆掉线
#tri {你的任务是去(*)守门。} {#t- job;%1} {job}
//注意,这里的做法很巧妙,用任务地点做为命令,请看下面定义的alias,你就会明白了
#alias {安定门} {do 3 s;do 3 w;n;n;guarding}
#alias {朝阳门} {do 4 s;e;guarding}
#alias {德胜门} {do 6 w;nw;guarding}
#alias {地安门} {do 3 s;do 3 w;s;guarding;}
#alias {东便门} {do 7 s;e;guarding}
#alias {东直门} {do 3 s;e;guarding}
#alias {阜成门} {do 3 s;do 7 w;do 3 s;guarding}
#alias {广安门} {do 3 s;do 7 w;do 9 s;guarding}
#alias {广渠门} {do 10 s;e;guarding}
#alias {西便门} {do 3 s;do 7 w;do 6 s;guarding}
#alias {西直门} {do 3 s;do 7 w;guarding}
#alias {宣武门} {do 7 s;do 7 w;guarding;}
#alias {永安门} {do 11 s;do 3 w;guarding}
#alias {右安门} {do 11 s;do 6 w;guarding}
#alias {正阳门} {do 7 s;do 3 w;s;guarding;}
#alias {左安门} {do 11 s;guarding}
#alias {崇文门} {do 7 s;guarding}
#alias {景山} {do 3 s;do 3 w;do 2 s;guarding;}
#alias {北海西门} {do 3 s;do 5 w;s;s;e;guarding;}
//步骤二：把所有天亮的天色描述做成trigger
//别忘了关掉tick timer，为了篇幅考虑，下面只给出所有的天色描述，trigger的做法完全一样
//最好为所有的天色描述去一个class名：天色，然后单独保存起来便于以后加载
#tri {【 天色 】风吹起来了，和着东升太阳的万道金光，清晨不似从前那般凉爽} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】金黄色的太阳刚从东方的地平线上冉冉升起} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】起风了，树木光秃秃的在风中瑟瑟的发抖} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】起风了，新发芽的枝叶在风中幽雅的摇弋着} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】起风了，一片片发黄的树叶，纷纷扬扬随风飘起} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】秋雨淅沥沥地下了起来，凉丝丝的} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】如雾的小雨带着春意，飘向每个闲情的窗口} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳从东方的地平线冉冉升起，放射着耀眼的光芒} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳从东方的地平线升起了} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳从东方的地平线升起了。一片红红的朝霞} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳从东方的地平线升起了，苍白无力地发射着光芒} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳从东方升起来了} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳刚从东方的地平线升起} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳露在东方的地平线上，显示了一天的勃勃生机} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳升起来了，躲在云层后面呼呼地喘着气} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳吞吐着万道金芒，跃出地平线，大地一片金黄} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】太阳在东方的天边吞吐着万道金光，太阳升起来了} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】天光终于放亮了，风裹着云在天上飞速的跑着} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】微风带着一缕泥土的芳香吹了起来，天光放亮了} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】细若牛毛的春雨淅沥沥地下了起来，早起的小鸟欢快地呢喃着} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】小雪夹杂着雨无声无息的下着} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】小雨正淅沥沥地下着} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】雪加着绵绵的小雨无声的下着，不一会地上就湿了} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】一道耀眼的金光倏的从东方的天边射了出来，一轮红日喷薄而出} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】一道耀眼的金光倏的从东方的天边射了出来，一轮红日升了起来} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】一道耀眼的金光倏的从东方的天边射了出来，一轮红日跃出天际} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】一轮红艳艳太阳刚从东方的地平线升起} {#timer off;ask duo about 守门} {天色}
#tri {【 天色 】又是一个新年的早晨，从东方的天边射了万道霞光，一轮红日跃出天际} {#timer off;ask duo about 守门} {天色}
//步骤三：制作守门过程
#tri {你一叉腰，对身旁的官兵道：*。} {#t+ 守门;#var success 进行中.....;#var zhuanghan 0;#var expgrain 0}
//这句话出现表示守门正式开始，打开守门class,接下来所有的触发都取一个class名:守门
//在定义status bar的时候要用到@success，用来显示守门前，守门成功，守门失败，守门进行中.....，守门被干扰5种情况，方便查看
//@zhuanghan和@expgrain也用在status bar中，用来查看守门过程中杀敌数目和守门奖励
#tri {江湖汉子快步走了过来。} {pancha jianghu hanzi} {守门}
#tri {壮汉快步走了过来。} {pancha zhuang han} {守门}
//盘查江湖汉子。白天守门任务有2类，其中之一需要盘查江湖汉子。
#tri {*对着(*)大喝道：挡我者死！} {#if (%1!=你) {#t- 守门;退出}} {守门}
#tri {江湖汉子一言不发，陡然向(*)发难。} {#if (%1!=你) {#t- 守门;退出}} {守门}
//其他玩家也在同一个地方守门，受到干扰，退出游戏
#tri {官兵拦住(*)说道：看告示了没有？您想进带着*进城呐？先问问*大人吧！} {#if (%1!="壮汉") {#var name %1;look}} {守门}
//官兵可能拦住壮汉，也可能拦住玩家蒙面杀手盗宝人，如果是后者，把名字保存到name中，同时用look来抓去玩家蒙面杀手或者盗宝人的id
#tri {@name~((*)~)} {#t- allow;#alarm +2 {#t+ allow};#var id %lower(%1);allow %lower(%1)} {allow}
//除去壮汉之外的所有人全部放行。有时候玩家可能会疯狂闯门，为了避免输入allow命令过多导致守门失败，在这个trigger触发之后短暂的关闭2秒再打开。
#tri {你一脚踢开江湖汉子的尸体，得意地笑了笑。} {#add zhuanghan 1;hp} {守门}
#tri {你踢了一脚} {#add zhuanghan 1;hp} {守门}
//守门任务有2类分别是杀江湖汉子和壮汉，做2个trigger来计算杀敌数目
#tri {你的经验增加了(*)！} {#var expgrain %1;#var success 成功;#wa 8000;#var zhanghao {};#var mima {};halt;#t- allow;#t- 守门;quit;#alarm +690 {#var zhanghao @zhanghao2;#var mima @mima2;#connect}} {守门}
//守门成功正常退出游戏之前，为@expgrain,@success赋值,关掉放行和守门2类trigger
//清空zhanghao,mima阻止自动连线，11分半之后zhanghao,mima的值还原，重新连线
#tri {你本次守门任务看来做得并不成功！} {#var success 失败;#wa 8000;#var zhanghao {};#var mima {};halt;#t- allow;#t- 守门;quit;#alarm +690 {#var zhanghao @zhanghao2;#var mima @mima2;#connect}} {守门}
//这是由于放行次数过多导致守门失败的trigger，尽管这种情况出现可能性非常小，还是必须要考虑到的，将@success的值改变为"失败"
#tri {慢慢地你终于又有了知觉....} {jifaskills;退出} {守门}
//有放行和受伤自动退出为你的安全作双重保障，但是仍然不能100%保证安全，这个trigger有必要加上
//这里jifaskills和退出都是alias，退出这个alias用于所有的非正常退出
#alias jifaskills {jifa dodge juemen-gun;jifa staff juemen-gun;jifa parry juemen-gun}
//没什么好说的，死了之后重新jifa
#alias 退出 {#var success 被干扰;#var zhanghao {};#var mima {};#var time [1440-%ctime-30];halt;quit;#alarm +@time {#var zhanghao @zhanghao2;#var mima @mima2;#connect}}
//mud中一天是24分钟，不论你何时退出游戏，只需要等待[1440-%ctime]秒之后就是天亮，这里为了提前半分钟上线，多减了30.退出前将success的值改为"被干扰".
//步骤四：仅仅有放行还是不够安全，加入受伤自动退出；如果你已经将挨打的信息都做成了trigger，那么只需要载入就可以了
#TRIGGER {( 你气喘嘘嘘，看起来状况并不太好。 )} {exert recover} {安全}
#TRIGGER {( 你似乎十分疲惫，看来需要好好休息了。 )} {exert recover} {安全}
#TRIGGER {( 你受伤过重，已经有如风中残烛，随时都可能断气。 )} {halt;#untr +@time;退出} {安全}
#TRIGGER {( 你摇头晃脑、歪歪斜斜地站都站不稳，眼看就要倒在地上。 )} {halt;er;#untr +@time;退出} {安全}
#TRIGGER {( 你看起来已经力不从心了。 )} {halt;#untr +@time;退出} {安全}
#TRIGGER {( 你受了相当重的伤，只怕会有生命危险。 )} {halt;#untr +@time;退出} {安全}
//注意:这几个trigger可能有多个被触发，而触发时间略有差异，那么就会同时创建好几个alarm类型的trigger,因此这里创建新的alarm类型trigger之前用#untr +@time删除旧的trigger
//步骤五：加入重新连线功能，并且做好守门之前的准备工作，吃饱喝足
#alias {atconnect} {@zhanghao;@mima;yes} {System}
#tri {欢迎来到北大侠客行！} {#var success 守门前;#t- 守门;#t- allow;#t- job;#timer off;#untr +@time;#untr +690;w;s;d;out;draw cloth;draw boots;draw head;draw surcoat;draw armor;remove all;wear all;draw staff;draw staff;wield all;#wa 4000;enter;u;hp;tell @zhanghao 已经全副武装} {准备}
//连线进入之后要做的事非常多，应该关闭的trigger全部关闭，tick timer关闭，没有及时删除的alarm也删除掉，改变success的值为"守门前"
//进入游戏领一套新手装,然后tell自己的id，然后用这句话做触发
#tri {*~(@zhanghao~)告诉你：已经全副武装} {s;s;w;drink;e;n;n;#if (@food<100) {n;n;e;buy ganliang} {#wa 3000;#say 准备就绪}} {准备}
//判断食物，小于100就去买干粮，否则准备就绪
#TRIGGER {你从店小二那里买下了一块干粮。} {#wa 3000;#10 eat ganliang;w;s;s;#wa 3000;#say 准备就绪} {准备}
#TRIGGER {穷光蛋，一边呆着去！} {#wa 3000;w;s;w;qu 30 silver;e;n;e;buy ganliang} {准备}
#TRIGGER {哟，抱歉啊，我这儿正忙着呢*您请稍候。} {#wa 3000;buy ganliang} {准备}
#tri {准备就绪} {#wa 2000;enter shudong;say 天堂有路你不走呀;d;3;ne;ne;u;sw;e;sd;e;e;do 3 ne;n;#wa 1500;do 3 e;u;e;do 4 n;#wa 1500;w;d;do 7 n;#timer off;ask duo about 守门} {准备}
//还需要抓取经验,食物和贡献度,直接载入就好了
#TRIGGER {【%s饮水%s】%s(%d)%s/%s%d*【%s经验%s】%s(%d)} {#var drink %1;#var exp %2} {hp}
#TRIGGER {【%s食物%s】%s(%d)%s/%s%d*【%s潜能%s】%s(%d)} {#var food %1;#var pot %2} {hp}
#TRIGGER {贡%s献%s度：%s&gongxian$} {} {score}
//步骤六：制作按钮，定义status bar
#button 0 {修改帐号} {#pr zhanghao "你的帐号";#pr mima "你的密码" "*";#var zhanghao2 @zhanghao;#var mima2 @mima}
#button 0 {删除alarm} {#untr +690;#untr +@time}
#st {杀死壮汉【@zhuanghan】个 获得经验【@expgrain】 当前经验 【@exp】 【贡献度@gongxian】 【守门@success】} |
狗仔卡
发表于 2010-1-10 11:49:59
提升卡
沉默卡
变色卡
显身卡
楼主