求解：tintin++如何抓取闲聊等信息，在独立（或split）窗口显示出来

dispensable

RT，实在是没办法了。。。真心找不到什么说明和他人的经验。搜索了好久没有结果才来麻烦大家。。。先谢过了。
新人表示窗口里的闲聊、谣言、宴会什么的信息太多了。都看不清任务了。能不能做一个触发来把这些信息显示在其他不打扰视线的地方呢？我用tintin++
再次感谢。

北大侠客行MUD，中国最好的MUD

yjqpro

有些聊天是多行的,这不好处理.

when

http://tintin.sourceforge.net/scripts/window.php

erq

这个怎么样？ 其实主要就是靠 #split 命令

erq

把屏幕分成了几个区域， 可以用 show_to_status, show_to_quest, show_to_info, show_to_chat 往不同的区域显示东西。

#class show open;
#split 17 1

#nop status/-/shortcut/-/5(info)/-/6(chat)/- = 17
#var info_window {{1}{ } {2}{ } {3}{ } {4}{ } {5}{ }};
#var chat_window {{1}{ } {2}{ } {3}{ } {4}{ } {5}{ } {6}{ }};

#var info_window_offset 4;
#math chat_window_offset $info_window_offset+&info_window[]+1;

#alias {show.init} {
        #alias {show_to_status} {
                #var show_status %%0;
                #echo {{${show_status}<099> => ${show_quest}<099>}{-1}};
        };

        #loop {1} {&info_window[]} {cnt}
        {
                #math pos $cnt+${info_window_offset};
                #echo {{$info_window[$cnt]<099>} {-$pos}};
        }

        #loop {1} {&chat_window[]} {cnt}
        {
                #math pos $cnt+${chat_window_offset};
                #echo {{$chat_window[$cnt]<099>} {-$pos}};
        }
};

#alias {show_to_shortcut} {
        #var show_key %0;
        #echo {{${show_key}<099>}{-3}};
};

#alias {show_to_info} {
        #format {tmp_time} {%t} {%T};
        #var temp ${tmp_time} <099> %0;
        #list info_window ins -1 $temp;
        #list info_window del 1;

        #loop {1} {&info_window[]} {cnt}
        {
                #math pos $cnt+${info_window_offset};
                #echo {{$info_window[$cnt]<099>} {-$pos}};
        }
}

#alias {show_to_chat} {
        #delay {chat_delay} {
                #format {tmp_time} {%t} {%T};
                #var temp ${tmp_time} <099> %0;
                #list chat_window ins -1 {$temp};
                #list chat_window del 1;

                #loop {1} {&chat_window[]} {cnt}
                {
                        #math pos $cnt+${chat_window_offset};
                        #echo {{$chat_window[$cnt]<099>} {-$pos}};
                }               
        } {0.5};
}

#alias {show_to_quest} {
        #var show_quest %0;
        #echo {{${show_status}<099> => ${show_quest}<099>}{-1}};
};

#gag {【闲聊】%*};
#action {【闲聊】%*} {
    show_to_chat %0;       
};

#gag {【谣言】%*};
#action {【谣言】%*} {
        show_to_chat %0;
};

#action {%1{回答|告诉}你：%2} {
        show_to_chat 【私聊】%0;
};

#action {你{回答|告诉}%1：%2} {
        show_to_chat 【私聊】%0;
};
#class show close;

hulai

多行的不行。

xxhy

又学到一招